home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / prgtools / programm.ing / falcon / asm56.zoo / chorus.a56 < prev    next >
Encoding:
Text File  |  1992-11-14  |  7.7 KB  |  237 lines
  1. ;***************************************************************
  2. ; 
  3. ; Stereo chorus for the DSP56001 signal processor.
  4. ; Developed by Quinn Jensen (jensenq@npd.novell.com).
  5. ; 
  6. ; This program fragment implements a stereo "chorus" effect
  7. ; on a DSP56001 processor.  Chorus adds depth and warmth to
  8. ; sound by creating the illusion that more instruments
  9. ; are involved in the sound than really are.  It does this by
  10. ; mixing together a delayed version of the input with the input
  11. ; itself.  This program uses the following signal flow.
  12. ;
  13. ;
  14. ;  Left in ------+------- "dry" gain -----------> sum -----> Left out
  15. ;                |                                 ^
  16. ;                v                                 |
  17. ;               sum --> delay ---> "wet" gain -----+
  18. ;                ^                                 |
  19. ;                |                                 v -
  20. ;  Right in -----+------- "dry" gain -----------> sum -----> Right out
  21. ;
  22. ;
  23. ; Note that the delay line output is negated before summing with the
  24. ; right input signal.  This throws in 180 degrees of phase shift
  25. ; making for interesting results even with mono inputs 
  26. ; (i.e. Left in == Right in).
  27. ; 
  28. ; Chorus uses a delay time of between about 10 and 50ms in some commercial
  29. ; units.  This program can be configured for longer delays.
  30. ; In the chorus effect, the delay time is slowly varied, adding a very
  31. ; subtle pitch shift.  The depth and speed of the delay-time modulation
  32. ; are adjustable to taste.  The greater the depth or speed, the greater
  33. ; the coloration of the signal.
  34. ;
  35. ; Variations in this algorithm are possible and encouraged.  I came
  36. ; up with this code after studying the impulse response and characteristics
  37. ; of a commercial stereo chorus pedal and reading various articles in magazines
  38. ; and on usenet over the years.  My somewhat dry TX81 synthesizer sounds pretty
  39. ; good with this and other effects I run on the 56001.
  40. ;
  41. ; A recent article with a pretty good not-too-technical overview of chorus 
  42. ; and other effects:  Gary Hall, "From the Top: Effects, the Essential Musical
  43. ; Spice," _Electronic Musician_, August 1991, pp. 62-68.
  44. ;
  45. ; I would enjoy seeing any improvements to the code.
  46. ;
  47. include 'tdsg.basic.a56'    ;hardware specific initialization code
  48.  
  49. ;***************************************************************
  50. ;
  51. ;    Data and constants
  52. ;
  53. ;***************************************************************
  54.  
  55. dot                ;remember where we were in P-space
  56.     org    x:$20        ;put runtime variables in on-chip X-space
  57.  
  58. ; A spreadsheet was used to calculate the following numbers
  59.  
  60. ; Sample rate              32.5500 kc         
  61. ; 
  62. ; Delay time (4-52)        28.0000 ms        delay time knob
  63. ; Depth (1-10)             10.0000        depth knob (I like it deep)
  64. ; Speed (1-10)              0.0000        speed knob (I like it slow)
  65. ; 
  66. ; max depth +/-            24.0000 ms         
  67. ; min delay                 4.0000 ms         
  68. ; max delay                52.0000 ms         
  69. ; 1/2 cycle period          5.0000 s          
  70. ; samples per 1/2 cyc  162750.0000
  71. ; time delta/samp           0.2949 us         
  72. ; offset samp/samp          0.0096
  73. ; 
  74.   doff_i equ                              -130    ;initial delay offset (tap)
  75.   ddeltaf equ                           0.0096    ;delta-delay, per sample
  76.   dspeed_i equ                          162750    ;number of samples per
  77.                         ;half cycle of triangle wave
  78.                         ;delay-time modulator
  79. ; 
  80. ; Delay time (ms)              tap                   tap     delay
  81. ; 
  82. ;                   1      32.5500                     1      0.03
  83. ;                   2      65.1000                     2      0.06
  84. ;                   4     130.2000                     4      0.12
  85. ;                   5     162.7500                     8      0.25
  86. ;                   8     260.4000                    16      0.49
  87. ;                  10     325.5000                    32      0.98
  88. ;                  20     651.0000                    64      1.97
  89. ;                  25     813.7500                   128      3.93
  90. ;                  40    1302.0000                   256      7.86
  91. ;                  50    1627.5000                   512     15.73
  92. ;                  60    1953.0000                  1024     31.46
  93. ;                  70    2278.5000                  2048     62.92
  94. ;                  80    2604.0000                  4096    125.84
  95. ;                  90    2929.5000                  8192    251.67
  96. ;                 100    3255.0000                 16384    503.35
  97.  
  98. ;
  99. ;    The delay line is in off-chip X memory
  100. ;
  101. delay    equ    $2000
  102. dmax    equ    4096        ;125 ms (probably way too long)
  103. ;
  104. ; doff and ddelta are 48-bit quantities
  105. ;
  106. doff    dc    doff_i        ;current delay distance
  107.     org    y:doff
  108.     dc    0
  109.  
  110.     org    x:doff+1
  111. ddelta    dc    0        ;delta delay per sample
  112.     org    y:ddelta
  113.     dc    ddeltaf
  114.  
  115.     org    x:ddelta+1
  116.  
  117. dspeed    dc    dspeed_i    ;samples per half cycle of triangle modulator
  118. dtoggle    dc    0        ;current sample count
  119. delayout
  120.     dc    0        ;current delay-line output
  121.  
  122.     org    y:$0
  123.  
  124.     org    p:dot        ;go back to P-space
  125. ;***************************************************************
  126. ;
  127. ; Initialization code
  128. ;
  129. ;***************************************************************
  130. hf_init
  131.     move    #delay,r1            ;delay line input
  132.      movec    #dmax-1,m1            ;
  133.     move    #doff_i,n1            ;distance to output
  134.     rts
  135. ;
  136. ;***************************************************************
  137. ;
  138. ;    Sample-rate computations.  Call chorus_compute at
  139. ;    interrupt time when both left and right inputs are
  140. ;    ready.
  141. ;
  142. ;    fs = 32.552083 kHz
  143. ;
  144. ;    x:<in_l        left-channel input
  145. ;    x:<in_r        right-channel input
  146. ;    x:<out_l    left-channel output
  147. ;    x:<out_r    right-channel output
  148. ;
  149. ;***************************************************************
  150.  
  151. hf_comp
  152.     jsr    <saveregs
  153. ;
  154. ;    output and input mix
  155. ;
  156.     clr    a    #.4375,x1        ;clr a, get input scale
  157.     clr    b    #.5,y1            ;clr b, get output scaler
  158.  
  159.     move        x:<delayout,y0        ;get delay out
  160.  
  161.     macr    y0,y1,b    x:<in_l,x0        ;b = .5 * delay, x0=in_l
  162.     macr    x0,y1,b        b,y0           ;b += .5 * in_l, y0=b
  163.     macr    x0,x1,a b,x:<out_l        ;a = x1 * in_l, L = b
  164.     move            y0,b        ;b = -y0
  165.     neg    b    x:<in_r,x0        ;x0 = in_r
  166.     macr    x0,y1,b                ;b += .5 * in_r
  167.     macr    x0,x1,a    b,x:<out_r        ;R = b, a += x1 * in_r
  168. ;
  169. ;    delay line in
  170. ;
  171.     move    a,x:(r1)+
  172. ;
  173. ;    delay line length modulation.  A simple triangle-wave modulator
  174. ;    is used.  A sine-wave modulator would be much better, especially
  175. ;    with deeper and/or faster settings.
  176. ;
  177.     move        l:<doff,a        ;a = current offset
  178.     move        l:<ddelta,x        ;x = current delta
  179.     add    x,a
  180.     move        a,l:<doff        ;new offset = a + x
  181.     move        a1,n1
  182.  
  183.     move        x1,b            ;save delta for later use
  184. ;
  185. ; smoothly transition between delay-line offsets by
  186. ; interpolating the current sample with the previous or next
  187. ; one depending on whether the delay is currently getting longer or
  188. ; shorter.  Otherwise, an obnoxious click results when the offset snaps
  189. ; to the next integral value.  This does have a low-pass effect on the
  190. ; delayed signal path but it is not objectionable.
  191. ;
  192.     move            y:<doff,a    ;compute |frac(doff)|
  193.     lsr    a    #$800000,x0
  194.     or    x0,a    #.5,x1
  195.     move        a1,x0
  196.     mpy    -x0,x1,a
  197.     tst    b        a,y0        ;y0 = 0.5 * |frac(doff)|
  198.     jpl    shorter                ;on positive delta, the
  199.                         ;delay is shortening
  200.  
  201.     move        (r1)-            ;get previous sample
  202.     move        x:(r1+n1),x0
  203.     mpy    y0,x0,a    #.5,b            ;scale
  204.     sub    y0,b    (r1)+            ;compute scale for cur sample
  205.     move            b,y0
  206.     move        x:(r1+n1),x0        ;get cur sample
  207.     mac    x0,y0,a                ;scale and sum
  208.     jmp    endpan
  209.  
  210. shorter
  211.     move        x:(r1+n1),x0        ;get cur sample
  212.     mpy    y0,x0,a    #.5,b            ;scale
  213.     sub    y0,b    (r1)+            ;compute scale for next sample
  214.     move            b,y0
  215.     move        x:(r1+n1),x0        ;get next sample
  216.     mac    x0,y0,a    (r1)-            ;scale and sum
  217. endpan
  218.     move        a,x:<delayout        ;store resulting output
  219. ;
  220. ; update the triangle wave modulation (sinewave would be better)
  221. ;
  222.     move        x:<dtoggle,a        ;decrement toggle count
  223.     move        #>1,x0
  224.     sub    x0,a
  225.     move        a,x:<dtoggle
  226.     jgt    notogg                ;time to toggle?
  227.     move        x:<dspeed,x0        ;yes, negate delta and reset
  228.     move        l:<ddelta,a
  229.     neg    a    x0,x:<dtoggle
  230.     move        a,l:<ddelta
  231. notogg
  232. bypass
  233.     jsr    <restregs
  234.     rts
  235.  
  236.     end
  237.